There are two ways to do inflection mapping, one with Mandelbrot iterations (inflect C, start iterating at Z = 0), and another with Julia iterations (inflect Z, iterate with C set to the first inflection point (last to be applied)).
Here's a Mandelbrot version in Fragmentarium:
http://www.fractalforums.com/images-showcase-%28rate-my-fractal%29/fruity-%28inflection-mapping%29/Here's a Julia version in Fragmentarium:
#include "Progressive2D.frag"
vec2 cMul(vec2 a, vec2 b)
{
return vec2(a.x * b.x - a.y * b.y, a.x * b.y + a.y * b.x);
}
vec2 cSqr(vec2 a)
{
return cMul(a, a);
}
vec4 cMul(vec4 a, vec4 b)
{
return vec4(cMul(a.xy, b.xy), cMul(a.xy, b.zw) + cMul(a.zw, b.xy));
}
vec4 cSqr(vec4 a)
{
return cMul(a, a);
}
#define N 6
const vec2 cs[N] = vec2[N]
( vec2(-0.75, 0.1)
, vec2(-0.7780062, 0.9591821)
, vec2(-0.7186571, 1.0251421)
, vec2(-0.5475953, 0.6401844)
, vec2(-0.5129835, 0.6237739)
, vec2(-0.4531227, 0.8943247)
);
vec3 color(vec2 c0)
{
float px = length(vec4(dFdx(c0), dFdy(c0)));
vec4 c = vec4(c0, px, 0.0);
for (int i = N-1; i >= 0; --i)
{
vec4 f = vec4(cs[i], 0.0, 0.0);
vec4 d = c - f;
c = cSqr(d) + f;
}
int n = 0;
vec4 z = c;
for (n = 0; n < 1000; ++n)
{
if (dot(z.xy, z.xy) >= 1.0e10)
break;
z = cSqr(z) + vec4(cs[0], 0.0, 0.0);
}
if (dot(z.xy, z.xy) < 1.0e10)
return vec3(1.0, 0.0, 0.0);
float r = length(z.xy);
float dr = length(z.zw);
float de = 2.0 * r * log(r) / dr;
float g = tanh(clamp(de, 0.0, 4.0));
if (isnan(de) || isinf(de) || isnan(g) || isinf(g))
g = 1.0;
return vec3(g);
}
Image of the Julia version:
March 07, 2011, 11:14:36 AM
Dilber MC Theme by HarzeM