END OF AN ERA, FRACTALFORUMS.COM IS CONTINUED ON FRACTALFORUMS.ORG

#include "DE-Raytracer.frag"
#group Hypercomplex Thing

// Number of fractal iterations.
uniform int Iterations;  slider[0,16,100]
// Breakout distance
uniform float Threshold; slider[0,10,100]
// Mandel or Julia
uniform bool JuliaMode; checkbox[false]

// Quaterion Constant (first three components - only used for Julia)
uniform vec3 C123; slider[(-1,-1,-1),(0.18,0.88,0.24),(1,1,1)]
// Quaterion Constant (last component)
uniform float C4; slider[-1,0.16,1]

vec4 c = vec4(C123,C4); // We don't support 4-component sliders yet...

void init() {}

vec4 mul(vec4 a, vec4 b) {
	return vec4(
		a.x*b.x - a.y*b.y - a.z*b.z + a.w*b.w,
	  a.x*b.y + a.y *b.x - a.z*b.w - a.w * b.z,
	a.x * b.z + a.z*b.x - a.w*b.y -a.y* b.w,
	a.x*b.w + a.w*b.x + a.y*b.z + a.z*b.y);
}

float DE(vec3 pos) {
	vec4 p = vec4(pos, 0.0);
	vec4 dp = vec4(1.0, 0.0,0.0,0.0);
	for (int i = 0; i < Iterations; i++) {
		dp = 2.0* mul(p,dp);
		p = mul(p,p) + (JuliaMode ? c : vec4(pos,C4));
		float p2 = dot(p,p);
		orbitTrap = min(orbitTrap, abs(vec4(p.xyz,p2)));
		if (p2 > Threshold) break;
	}
	float r = length(p);
	return  0.5 * r * log(r) / length(dp);
}