3d Bifurcation in Mandelbulb3d?

[Chillheimer]

I would like to visualize a 3d bifurcation like this:


But looking awesome. Any tips how to achieve this in Mandelbulb3d? (or maybe even parameters I could play with?)

Thx for any help..
 

[quaz0r]

... but looking awesome

  

[msltoe]

Do you have the coordinates of the dots? If so, you can convert to a scene format and then use any number of 3-D renderers.
Mandelbulb3D (I think) is primarily an escape time fractal program, but bifurcations like the ones you presented are a different type of fractal.
If you can find the formula that these things use, one of us should be able to whip up a program to generate a scene file (list of spheres, e.g)
that can then be rendered with a standard raytracing program.

[Chillheimer]

I guess that would be the formula then:
https://en.wikipedia.org/wiki/Bifurcation_diagram#Logistic_map

[hobold]

This can be done within PoV-Ray ( http://www.povray.org ).

It's not an appropriate tool, and the example below is probably not the best way, but it might be a start.

Code:

#version 3.7;

#global_settings {
  assumed_gamma 1.0
}

camera {
  location  <0, 2, 10>
  direction <0, 0, -2>
  up        <0, 1, 0>
  right     <1, 0, 0>
  sky       <0,1,0>
  look_at   <0, 1, 0>
}

// spline path through Mandelbrot set
// left number is spline parameter, i.e. tree height
// right vector is point in complex plane
#declare mandelPath = spline {
  natural_spline
  0.0 <  0.0,  0.0>
  1.0 < -2.0,  0.0>
}


#declare numPts = 4000;  // number of points to be rendered
#declare treeHeight = 2.0;  // height of treetop

#declare iterSkip = 100;  // do not display first 100 iterations

#declare curPt = 0;

union {  // group all spheres together

#while (curPt < numPts)
  #declare curT = curPt/(numPts - 1);     // current spline parameter
  #declare curHeight = treeHeight*curT;   // current point height
  #declare curC = mandelPath(curT);       // current constant C

  #declare Zr = 0;
  #declare Zi = 0;
  #declare Zr2 = 0;
  #declare Zi2 = 0;
  #declare iter = 0;  

  #declare numIters = iterSkip + curPt;

  #while (((Zr2 + Zi2) <= 4) & (iter < numIters))
    #declare iter = iter + 1;
    #declare Zi = 2*Zr*Zi + curC.v;
    #declare Zr = Zr2 - Zi2 + curC.u;
    #declare Zr2 = Zr*Zr;
    #declare Zi2 = Zi*Zi;
  #end

  #if (iter = numIters)
    sphere { <Zr, curHeight, Zi>, 0.025 }
  #end

  #declare curPt = curPt + 1;
#end

texture {
  pigment {rgb <0.5, 0.5, 0.5>}
  finish {
    ambient 0.0
    diffuse 0.8
    specular 0.35
    roughness 0.04
  } 
}

}  // close union around all spheres

// ground box
box {<-1, -1, -1>, <1, 0, 1>
  texture {
    pigment {rgb <0.5, 0.5, 0.5>}
    finish {
      ambient 0.0
      diffuse 0.8
      specular 0.35
      roughness 0.04
    } 
  }
}

light_source { <18, 15, 8> color rgb <.6, .7, .8>}
light_source { <-18, -10, -8> color rgb <.8, .7, .6>}

background { color rgb <0.3, 0.5, 0.8> }

[hgjf2]

It can make so 3D biffurcation and for 2d classic Mandelbrot if take whole complex space for the other line than real number set.
Example: for Mandelbrot set fc(z)=z^2+c, taking c=0,1+ik one examplu, and for each Julia set f=z^2+0,1+ik rendering the point of attraction whick isn't real number but is complex number , then the bifurcation with one dimensional curves need 3 dimensions (k axis, real numbers for this Julia set axis and imaginary numbers for this Julia set axis). I posted allready one example for this 3D biffurcation on DEVIANTART, an image named "3D attraction" on
HGJF-RADIOLARIA.DEVIANTART.COM . This my images can be watched stereographic in 3D in crosseyed mode.

[Chillheimer]

hobold, this is abolutely out of the reach of my abilities..
@hgjf2: I can't find that picture on your deviantart.. mind to link directly?

I found some nice amazing-box parameters.. they are not exactly the bifurcation I was aiming for, but they look very cool, will post here

[hobold]

Surprisingly rich structures in there: large strands, intertwined braids, balconies ...

[Chillheimer]

fascinating!

[hobold]

Animation of the above picture:

http://vectorizer.org/mandelbrot/mandeltree01.mp4

I feel a title for this one coming to me ... ah yes: "Turning the Cables".