Welcome to Fractal Forums

SmoothAtan2 {
init:
  complex zold = #z ; for previous z value so we have penultimate z at the end
  int i = 0 ; just an iteration count

loop:
  zold = #z ; store old z - note that because this is a colouring in UF this loop code is *not* called on the bailout iteration
  i = i + 1 ; again this is not called on the bailout iteration, so the value of i in the final section will be zero if the formula bails out on the first iteration

final:
  float lm = log(|#z|)                                         ; log of the final magnitude^2
  float f = log(lm) - log(log(@bailout))
  if i>0                                                            ; if didn't bailout on first iteration
    f = f/log(lm/log(|zold|))                                 ; use estimated divergence as log(|#z|)/log(|zold|)
  else
    f = f/log(@diverge)                                       ; user supplied divergence estimate
  endif

  float a1 = atan2(zold)                                     ; colouring value for penultimate iteration
  if @method==0
    a1 = abs(a1)
  elseif a1<0.0
    a1 = 0.5*(a1 + 2.0*#pi)
  endif

  float a2 = atan2(#z)                                     ; colouring value for final iteration
  if @method==0
    a2 = abs(a2)
  elseif a2<0.0
    a2 = 0.5*(a2 + 2.0*#pi)
  endif

  #index = (f*a1+(1.0-f)*a2)/#pi                     ; smooth - note that the /#pi is just for the atan2 colouring, obviously other colourings may require different scale factors

default:
  title = "SmoothAtan2"
  param bailout
    caption = "Bailout"
    default = 128.0
  endparam
  param diverge
    caption = "Estimated divergence"
    default = 2.0
    hint = "Only used hen bailout occurs on the first iteration."
  endparam
  param method
    caption = "Angle method"
    enum = "Absolute" "All"
    default = 0
  endparam
}