Welcome to Fractal Forums

vec3 cosineDirection(in vec3 nor)
{//return a random direction on the hemisphere
	vec2 r = rand2()*6.283;
	vec3 dr=vec3(sin(r.x)*vec2(sin(r.y),cos(r.y)),cos(r.x));
	return (dot(dr,nor)<0.0)?-dr:dr;
}
vec3 coneDirection(in vec3 nor, float ratio)
{//return a random direction within a cone where ratio is width/length
	vec3 up=(dot(vec3(0.0,1.0,0.0),nor)>0.9)?vec3(1.0,0.0,0.0):vec3(0.0,1.0,0.0);
	vec3 rt=normalize(cross(up,nor));up=cross(nor,rt);
	vec2 r=rand2();r=sqrt(r.y)*vec2(cos(r.x*6.283),sin(r.x*6.283));
	return normalize(nor+(rt*r.x+up*r.y)*ratio);
	//return normalize(nor+cosineDirection(nor)*ratio);//faster but even less correct
}

vec3 getSample(vec3 dir, float extent) {
	// Create orthogonal vector (fails for z,y = 0)
	vec3 o1 = normalize(vec3(0., -dir.z, dir.y));
	vec3 o2 = normalize(cross(dir, o1));
	
	// Convert to spherical coords aligned to dir
	vec2 r = getUniformRandomVec2();
	r.x=r.x*2.*PI;
	r.y=1.0-r.y*extent;

	float oneminus = sqrt(1.0-r.y*r.y);
	return cos(r.x)*oneminus*o1+sin(r.x)*oneminus*o2+r.y*dir;
}

vec3 getSampleBiased(vec3  dir, float power) {	
	// create orthogonal vector (fails for z,y = 0)
	vec3 o1 = normalize( vec3(0., -dir.z, dir.y));
	vec3 o2 = normalize(cross(dir, o1));
	
	// Convert to spherical coords aligned to dir;
	vec2 r = rand(viewCoord*(float(backbufferCounter)+1.0));
	if (Stratify) {r*=0.1; r+= cx;}
	r.x=r.x*2.*PI;
	r.y = 1.0-r.y;

	// This should be cosine^n weighted.
	// See, e.g. http://people.cs.kuleuven.be/~philip.dutre/GI/TotalCompendium.pdf
	// Item 36
	r.y=pow(r.y,1.0/(power+1.0));

	float oneminus = sqrt(1.0-r.y*r.y);
	vec3 sdir = cos(r.x)*oneminus*o1+
	sin(r.x)*oneminus*o2+
	r.y*dir;
	
	return sdir;
}