Welcome to Fractal Forums

  push  ecx                 //added OTrap coloring  + speedup
  add   esp, -32            //HeightMap  [nr: Int; Xoff, Yoff, Hoff, Xscale, Yscale, Hscale, Rotation: SRotMat, Col nr, Col OTrap, Col off, Col mult
  fld   qword [esi - 104]   //             -12     -16   -20   -24    -28      -32    -36       -40..-72          -76      -80      -84      -88
  fld   qword [esi - 112]
  fld   qword [esi - 120]   //x,y,z
//{rotation of x,y,z snipped}
  fld  st(2)               //speedup: calc map only if distance to surface is less than...
  fadd dword [edi - 24]    //z+Z(H)offset, x,y,z
  fld  dword [edi - 36]    //Hscale,z', x,y,z
  fmul qword [edi - 8]     //Hscale*0.5,z', x,y,z
  fsubp
  fabs                     //Abs(z'-Hscale*0.5), x,y,z
  fld  dword [edi - 36]
  fabs
  fadd qword [esi - 136]   //In dIFS: local DEstop value, add to distance
  fcompp                   //compare DEstop+Abs(Hscale) with Abs(z'-Hscale*0.5)
  fnstsw ax
  shr ah, 1
  jnc @@1
  fcompp                    //nz (x,y not needed anymore)  not close to surface: calculate distance to midpoint (0.5) of map
  fld   qword [edi - 8]     //0.5
  fmul  dword [edi - 36]    //amplitude H scale
  fsub  dword [edi - 24]    //H offset
  fsubrp                    //-z
  fstp  qword [esi - 32]    //Rout: Double; +56  is distance
  add   esp, 32
  pop   ecx
  ret
@@1:
  fmul  dword [edi - 28]
  fsub  dword [edi - 16]    // offsets after rot+scale
  fstp  qword [esp]
  fmul  dword [edi - 32]
  fsub  dword [edi - 20]
  fstp  qword [esp + 8]
  fstp  qword [esp + 24]
  mov   eax, esp            //esp contains 3d double vec, only x and y is used as map coord
  mov   edx, [edi - 12]
  mov   ecx, esp            //store result in same 3d vec 
  call  [esi + 268]         //+356 - 88 = 268
//   PMapFunc2:  esi+356    //   eax             edx             ecx
//function GetMapPixelDirectXY(PVec3D: TPVec3D; MapNr: Integer): TVec3D; //Direct pixel coords 0..1 with tiling
  mov   ecx, [edi - 76]    
  and   ecx, 3              //make sure no access beyond stack is possible
  fld   qword [esp + ecx * 8]   //col of map
  fmul  dword [edi - 36]    //amplitude H scale
  fsub  dword [edi - 24]    //H offset
  fsub  qword [esp + 24]    //-z
  fstp  qword [esi - 32]    //Rout: Double; +56  is distance
  mov   ecx, [edi - 80]     //Otrap color mapnr
  and   ecx, 3
  fld   qword [esp + ecx * 8]   //col of map
  fadd  dword [edi - 84]
  fmul  dword [edi - 88]
  fstp  qword [esi + 128]   //dfree1 for otrap coloring
  add   esp, 32
  pop   ecx
  ret

... // unchanged "preparation"
01006454     DD4414 10      FLD QWORD PTR SS:[ESP+EDX+10] // z or something ;)
01006458     D9E1           FABS // abs(z) - 1st term of comparation
0100645A     DD47 B8        FLD QWORD PTR DS:[EDI-48] // this controls how much it extrudes
0100645D     DC0F           FMUL QWORD PTR DS:[EDI] // multiply by 1.5
0100645F     90             NOP
01006460     D9E1           FABS // take abs for safety
01006462     DC47 08        FADD QWORD PTR DS:[EDI+8] // add 0.25 -> render a thin slice for a 'zero' extrusion
01006465     90             NOP
01006466     DED9           FCOMPP
01006468     DFE0           FSTSW AX
0100646A     D0EC           SHR AH,1
0100646C     73 0B          JNB SHORT twunk_32.01006479
0100646E     DD4414 10      FLD QWORD PTR SS:[ESP+EDX+10] // fail, we are far away from the plane. Load z
01006472     D9E0           FCHS // -z is the distance we return
01006474     E9 DA000000    JMP 01006553 // jumps to CMP DWORD PTR DS:[EDI-4C],0 ... and finish the computation
...// unchanged "real formula"