Welcome to Fractal Forums

Hi all,

On one of the maths lists they were recently discussing the near identity: pi^5 + pi^4 = e^6

So I decided to try the standard complex escape-time Mandy for z^n + z^(n-1) - #pixel^(n+1) and the results are QI ;)

e.g. try plain z^2 + z - #pixel^3 with a start of (-0.5,0)

I also tried the reverse i.e.

z^p - sigma(#pixel^n) for n either from 0 to p-1 or from 1 to p-1

Results also QI.

Am currently engaged more in processing my photos (have around 10 days of shots to process) rather than fractalling so I thought I'd mention this in case anyone wants to try the same formulas but using 3D+ math....I'd be especially interested in the results using the various triplex methods ;)

Note correction in previous post i.e. p-1 instead of n-1 !!!

Here are two Ultra Fractal formulas (Mandelbrot and Julia) for the problem that Dave discussed.  Yes, I stole the idea from him!

pi4+pi5-e6-mandelbrot {
;
; motivated by the near coincidence: pi^4 + pi^5 ~ e^6
;
; formula by Kerry Mitchell; idea stolen from Dave Makin
;
init:
  complex cnm1pcn=#pixel^(@power-1)+#pixel^@power
  complex cnp1=#pixel^(@power+1)
  complex z=@initial_z
loop:
  if(@pi_type=="z")
    z=z^(@power-1)+z^@power-cnp1
  elseif(@pi_type=="pixel")
    z=cnm1pcn-z^(@power+1)
  endif
bailout:
  |z|<@bailout
default:
  title="pi^4 + pi^5 - e^6 Mandelbrot"
  heading
    text="Critical points at 0, (1 - power) / power"
  endheading
  complex param initial_z
    caption="initial z"
    default=-0.8
  endparam
  complex param power
    caption="power"
    default=5
  endparam
  param pi_type
    caption="pi type"
    default=0
    enum="z" "pixel"
  endparam
  float param bailout
    caption="bailout"
    default=1000
  endparam
switch:
  type="pi4+pi5-e6-julia"
  julparam=#pixel
  power=power
  pi_type=pi_type
  bailout=bailout
}

pi4+pi5-e6-julia {
;
; motivated by the near coincidence: pi^4 + pi^5 ~ e^6
;
; formula by Kerry Mitchell; idea stolen from Dave Makin
;
init:
  complex cnm1pcn=@julparam^(@power-1)+@julparam^@power
  complex cnp1=@julparam^(@power+1)
  complex z=#pixel
loop:
  if(@pi_type=="z")
    z=z^(@power-1)+z^@power-cnp1
  elseif(@pi_type=="pixel")
    z=cnm1pcn-z^(@power+1)
  endif
bailout:
  |z|<@bailout
default:
  title="pi^4 + pi^5 - e^6 Julia"
  complex param julparam
    caption="Julia parameter"
    default=(0,1)
  endparam
  complex param power
    caption="power"
    default=2
  endparam
  param pi_type
    caption="pi type"
    default=0
    enum="z" "pixel"
  endparam
  float param bailout
    caption="bailout"
    default=1000
  endparam
switch:
  type="pi4+pi5-e6-mandelbrot"
  power=power
  pi_type=pi_type
  bailout=bailout
}