News: Visit the official fractalforums.com Youtube Channel

The All New FractalForums is now in Public Beta Testing! Visit FractalForums.org and check it out!

 Pages: [1]   Go Down
 Author Topic: Sierp-Tardis - parameters  (Read 301 times) Description: 0 Members and 1 Guest are viewing this topic.
VanlindtMarc
Conqueror

Posts: 130

 « on: November 22, 2013, 06:04:24 PM »

Code:
set maxobjects 1000000

#define majus 1.618
#define minus 0.618
#define profondeur 10
#define taillebarre 1/5
#define letmat box
test
rule test md 6
{
tardis
{x 3 y 0.6 s 0.618}test
{z 3 y 0.6 s 0.618}test
{y 3 s 0.618}test
}

rule tardis
{
laboite
face
{ry 90}face
{ry 180}face
{ry 270}face
panneau
ouvertures
{y 1.8}chapeau
{y 2.6 s 0.05}chapeau2

}

rule chapeau2
{chapeaupart2
chapeaupart3
{y -0.5 color white s 0.85}sphere}

rule chapeau md 128
{
{color #00a}box
{y 0.015 s 0.98}chapeau
}

rule laboite
{{y -0.05 s 1.1 0.025 1.1 color #00A }box
{ s 1.075 0.1 1.075 color #00A }box

{y 1.125 s 1 2.25 1 color #00a}box

{x -0.48 z 0.48 y 1 s 0.1 2 0.1 color #00A}box
{x 0.48 z 0.48 y 1 s 0.1 2 0.1 color #00A}box
{x -0.48 z -0.48 y 1 s 0.1 2 0.1 color #00A}box
{x 0.48 z -0.48 y 1 s 0.1 2 0.1 color #00A}box

{x -0.48 y 1 s 0.1 2 0.1 color #00A}box
{x 0.48 y 1 s 0.1 2 0.1 color #00A}box
{z -0.48 y 1 s 0.1 2 0.1 color #00A}box
{z 0.48 y 1 s 0.1 2 0.1 color #00A}box
}

rule face
{{z 0.48 y 1 s 1 0.1 0.1 color #00a}box
{z 0.48 y 0.5 s 1 0.1 0.1 color #00a}box
{z 0.48 y 1.5 s 1 0.1 0.1 color #00a}box
{z 0.48 y 2 s 1.055 0.1 0.1 color #00a}box
{z 0.49 y 2.15 s 0.95 0.15 0.1 color #00a}box
{z 0.49 y 2.15 s 0.925 0.125 0.11 color #111}box
{z 0.51 x -0.45 y 2.15 s 0.04 color #fff} tardistext1
{z 0.53 x -0.04 y 2.169 s 0.0225 color #fff} tardistext2
{z 0.53 x -0.02  y 2.119 s 0.0225 color #fff} tardistext3
}

rule panneau
{
{z 0.365 y 1.25 x -0.2325 s 0.3 color white}box
}

rule ouvertures
{
{z 0.5 y 1.25 x -0.065 s 0.01 0.04 0.04 color #00a}box
{z 0.55 y 1.25 x 0.0235 s 0.01 0.08 0.04 color #00a}box
}

rule chapeaupart2{
{x 0.5 z 0.5 y -0.5 s 0.1 2 0.1 color #00f}box
{x -0.5 z 0.5 y -0.5 s 0.1 2 0.1 color #00f}box
{x 0.5 z -0.5 y -0.5 s 0.1 2 0.1 color #00f}box
{x -0.5 z -0.5 y -0.5 s 0.1 2 0.1 color #00f}box
{y -0.5 z 0.5 s 1 0.1 0.1 color #00f}box
{y -0.5 z -0.5 s 1 0.1 0.1 color #00f}box
{y -0.5 x 0.5 s 0.1 0.1 1 color #00f}box
{y -0.5 x -0.5 s 0.1 0.1 1 color #00f}box}
rule chapeaupart3 md 64
{{y 0.5 s 1 0.1 1 color #00f}box
{y 0.075 s 0.9}chapeaupart3}

rule tardistext1
{
{x 1 s  minus minus profondeur} lettreP
{x 2 s  minus minus profondeur} lettreO
{X 3 s  minus minus profondeur} lettreL
{X 4 s  minus minus profondeur} lettreI
{X 5 s  minus minus profondeur} lettreC
{X 6 s  minus minus profondeur} lettreE
{X 19 s  minus minus profondeur} lettreB
{X 20 s  minus minus profondeur} lettreO
{X 21 s  minus minus profondeur} lettreX

}

rule tardistext2
{
{x 1 s  minus minus profondeur} lettreP
{x 2 s  minus minus profondeur} lettreU
{X 3 s  minus minus profondeur} lettreB
{X 4 s  minus minus profondeur} lettreL
{X 5 s  minus minus profondeur} lettreI
{X 6 s  minus minus profondeur} lettreC
}

rule tardistext3
{
{x 1 s  minus minus profondeur} lettreC
{x 2 s  minus minus profondeur} lettreA
{X 3 s  minus minus profondeur} lettreL
{X 4 s  minus minus profondeur} lettreL
}

// Fichier vide avec Text-MOD
// Empty file with Text-MOD
// Write EisenScript code here...
//////////////////////////////////////////////////////////////////////////////////////////////////
// Text-Mod (by Vanlindt Marc - vanlindtmarc.blogspot.be - vanlindt.marc@gmail.com )
//////////////////////////////////////////////////////////////////////////////////////////////////
// Example :
//////////////
//
// sstext
//
// rule sstext
// {
// {x 1 s  majus majus profondeur} lettreS
// {X 3 s  minus minus profondeur} lettreT
// {X 4 s  minus minus profondeur} lettreR
// {X 5 s  minus minus profondeur} lettreU
// {X 6 s  minus minus profondeur} lettreC
// {X 7 s  minus minus profondeur} lettreT
// {X 8 s  minus minus profondeur} lettreU
// {X 9 s  minus minus profondeur} lettreR
// {X 10 s  minus minus profondeur} lettreE
// {X 12 s  minus minus profondeur} lettreS
// {X 13 s  minus minus profondeur} lettreY
// {X 14 s  minus minus profondeur} lettreN
// {X 15 s  minus minus profondeur} lettreT
// {X 16 s  minus minus profondeur} lettreH
// }
//
// L'utilisation est simple.
// Comme on peut le voir dans l'exemple, il faut compter un espacement de 2 après une MAJUSCULE et de 1 après une minuscule.
// Pour que cela fonctionne, appliquez une redimensionnement de 1.618 aux MAJUSCULES et de 0.618 aux minuscules.
//
///////////////
// LETTRES //
///////////////
rule lettreA { BV {y 1} BO1{y 1} BH {x 1}BV {y 1 x 1} BV }
rule lettreB { BV {y 1} BV {y 2} BV BH {x 1} BV {y 1} BO2 }
rule lettreC { BH BV {y 1} BO1 }
rule lettreD { BV BH {y 1} BO1 {X 1} BV {x 1 y 1 } BV {x 1 y 2 } BV }
rule lettreE { BH BV {y 1} BO1 {y 1} BH }
rule lettreF { BV {y 1} BV {y 2} BO1 {y 2} BH }
rule lettreG { BH BV {y 1 } BO1 {x 1 y 1}BV {x 1}BV { y -1}BO1 }
rule lettreH { BV {y 1}BV {y 2}BV {y 1}BO2 {x 1}BV }
rule lettreI { {x 0.5} BV {x 0.5 y 1} BV}
rule lettreJ { {x 1} BV {x 1 y 1} BV {y -1}BO1}
rule lettreK { BV {y 1}BV {y 2}BV {y 1}BO1 BO2}
rule lettreL { {y 2}BV {y 1}BV BO2 }
rule lettreM {  {x 0.5} BV {x 1.5}BV {X 1.5 y 1}BV {x 0.5 y 1}BO1 {y 1 x 1.5}BO1 {y 1 x 2.5 } BV {x 2.5 } BV}
rule lettreN  { BV {x 1}BV {X 1 y 1}BV {y 1}BO1 }
rule lettreO { BV BH {x 1} BV {X 1 y 1}BV {y 1}BO1 }
rule lettreP { BV {y 1}BV {y -1}BV BH {x 1}BV {y 1} BO2 }
rule lettreQ { BH BV {y 1}BO1 {x 1 y 1}BV {x 1}BV {x 1 y -1}BV }
rule lettreR { BV {y 1}BV {y 1}BO1 }
rule lettreS { {y 1}BH BO1{y 1} BO1 }
rule lettreT { BO2 {y 1} BV {y 2}BV {y 2} BH }
rule lettreU { BO2 {y 1}BV {x 1}BV {y 1 x 1} BV }
rule lettreV { BV {y 1} BV {y 1 x 1} BV BO1}
rule lettreW {{ x 0.5} BV {x 0.5 y 1} BV {y 1 x 1.5 } BV {x 0.5} BO1 {x 1.5}BV {x 1.5}BO1 {x 2.5 y 1}  BV}
rule lettreX {{y 1 s 1 2 1}BO1 {y 1 s 1 2 1}BO2 }
rule lettreY { {y 1} BV BO2 {x 1}BV {X 1 y 1}BV {y -1}BO1}
rule lettreZ { BO2 {y 1}BO2 {y 1}BH }

////////////////
// ACCENTS //
///////////////
rule AccentAIGU {{y 2 s 1 0.5 1 } BO1}
rule AccentGRAVE {{y 2 s 1 0.5 1 } BO2}
rule AccentCIRC {{y 2 x 0.5 s 0.5 0.5 1 } BO2 {y 2 s 0.5 0.5 1 } BO1}
rule accentTREMA  {{ y 1.5 x 0.25 s 1/10} box { y 1.5 x 0.75 s 1/10} box }

////////////////
// CHIFFRES //
///////////////
rule chiffre1 { {x 1} BV  {x 1 y 1} BV {y 1 s 1 0.5 1 }BO1}
rule chiffre2 {BV BH {y 1}BH {y 2}BH {y 1 x 1 }BV }
rule chiffre3 { {x 1} BV {x 1 y 1}BV BH {y 1}BH {y 2}BH }
rule chiffre4 { {y 1}BV {y 1}BH {x 1}BV {x 1 y 1}BV }
rule chiffre5 {{x 1} BV {y 1}BV BH {y 1}BH {y 2}BH }
rule chiffre6 {BH {y 1}BH {y 2}BH BV {x 1}BV {y 1}BV }
rule chiffre7 {{x 1}BV {x 1 y 1}BV {y 2} BH {y 0.5 x 0.5 s 0.5}BH }
rule chiffre8 {BH {y 1}BH {y 2}BH BV {y 1}BV {x 1 y 1}BV {x 1}BV }
rule chiffre9 {BH {y 1}BH {y 2}BH {y 1}BV {x 1 y 1}BV {x 1}BV }
rule chiffre0 {BH {y 2}BH BV {y 1}BV {x 1 y 1}BV {x 1}BV  {y 1 s 1 2 1} BO1}

///////////////////////////////
// CARACTERES SPECIAUX //
///////////////////////////////
rule caractere- {{y 1} BH}
rule caractere+ {{y 1} BH {y 0.5 x 0.5} BV}
rule caractere* {{y 0.5 }BO1 { y 0.5}BO2}
rule caractereDIV {{y 1} BH { y 0.5 x 0.5} mybox { y -0.5 x 0.5 } mybox}
rule caractere: { {x 0.5 }mybox {y -1 x 0.5 }mybox}
rule caracterePOINT {{y -1 x 0.5 }mybox}
rule caractere/ { {y  1 s 1 2 1}BO1 }
rule caractere\ { {y  1 s 1 2 1}BO2 }
rule caractere= { {y 1.25} BH {y 0.75} BH }
rule caractere" {{y 1.5 x 0.5 s 1 0.5 1} BV {y 1.5 x 1 s 1 0.5 1} BV }

///////////////////////////////////////////////////////////////////////////
// DIFFERENTS BORDS UTILISES POUR FORMER LES CARACTERES //
//////////////////////////////////////////////////////////////////////////
rule BV { {y -0.5 s taillebarre 1 taillebarre} letmat}
rule BH {{y -1 x 0.5 s 1 taillebarre taillebarre} letmat}
rule BO1 {{ y -0.5 x 0.5 rz -45 } BOBL}
rule BO2 {{ y -0.5 x 0.5 rz 45 } BOBL}
rule BOBL {{ s taillebarre 1.41 taillebarre} letmat}
rule mybox {{s taillebarre}letmat}

 Logged

 Pages: [1]   Go Down